avp/guix.scm

;; Guix package for avp. To build or install, run from the toplevel directory:
;;
;;   guix build --file=guix.scm
;;   guix package --install-from-file=guix.scm
;;
;; To create and enter a development environment:
;;
;;   guix shell --pure --development --file=guix.scm

(use-modules
 (gnu packages audio)
 (gnu packages gl)
 (gnu packages sdl)
 (gnu packages video)
 (guix build-system cmake)
 (guix build utils)
 (guix gexp)
 (guix git-download)
 (guix packages)
 (ice-9 popen)
 (ice-9 rdelim))

(define (git-version directory)
  (with-directory-excursion directory
    (read-line (open-pipe* OPEN_READ "git" "describe" "--always" "--tags"))))

(define license (@@ (guix licenses) license))

(define source-dir (dirname (current-filename)))

(define-public avp
  (package
    (name "avp")
    (version (git-version source-dir))
    (source (local-file source-dir #:recursive? #t #:select? (git-predicate source-dir)))
    (build-system cmake-build-system)
    (arguments
     (list #:tests? #f))
    (inputs
     (list ffmpeg mesa openal sdl2))
    (home-page "https://sr.ht/~jetomit/avp")
    (synopsis "Aliens Versus Predator game engine")
    (description "Unofficial Linux port of the game engine for the Rebellion
Developments game Aliens Versus Predator.  This package does not
provide game assets.")
    (license (license "avp" "file:///LICENSE" "Aliens Versus Predator license"))))

avp